#Начало
	if QSPVER<'5.7.0':
		if USEHTML:
			*P '<h1>Устаревшая версия QSP</h1>'
			*P '<p align=justify>Версия QSP-плеера, который вы используете, устарела. Для игры требуется версия не ниже 5.7.0. Скачать последнюю версию вы всегда можете с сайта <a class="plain" href="http://qsp.su">qsp.su</a>.</p>'
		else
			*NL 'Устаревшая версия QSP'
			*NL 'Версия QSP-плеера, который вы используете, устарела. Для игры требуется версия не ниже 5.7.0. Скачать последнюю версию вы всегда можете с сайта http://qsp.su.'
		end
		EXIT
	end
	!----------
	KILLALL & CLS & CLOSE ALL
	!----------
	ADDQST 'libs\ObjectQSP.qsp' & GS 'ObjectQSP.Инициализация',0
	!----------
	!Загружаем визуальную тему игры
	GS 'Темы.Загрузить','Default'
	!----------
	GS 'ЗаполнитьДанные'
	!----------
	GS 'Игра.Начать'
	!----------
	--- Начало
	!-------------------------------------------------------------------------------
#ЗаполнитьДанные
	!Добавляем локации
	GS 'СоздатьЛокацию','Лужайка'
	!----------
	!Добавляем персонажей
	GS 'СоздатьПерсонажа','Игрок'
	!----------
	!Добавляем предметы
	GS 'СоздатьПредмет','Яблоко'
	!----------
	!Добавляем объекты
	GS 'СоздатьПредмет','Сумка'
	GS 'СоздатьПредмет','Чугунок'
	!----------
	!Заполняем игровой сценарий пообъектно
	GS 'Игра.ЗаполнитьОбъекты'
	!----------
	--- ЗаполнитьДанные
	!-------------------------------------------------------------------------------
#Локации.Лужайка.Заполнить
	GS 'УстановитьОписание','Лужайка','Лужайка','
		п. Вы сидите на залитой солнцем лужайке. Рядом валяется ((сумка|Сумка)), а перед вами стоит ((чугунок|Чугунок)).
	'
	!----------
	--- Локации.Лужайка.Заполнить
	!--------------------------------------------------------------------------------
#Предметы.Яблоко.Заполнить
	GS 'УстановитьОписание','Яблоко','яблоко','
		п. Здоровенное спелое ((яблоко|Яблоко)).
	'
	!----------
	GS 'УстановитьУпоминание','Яблоко:Упоминание в описании','Лужайка:Описания','п. На траве лежит красное ((яблоко|Яблоко)).',{
		killvar 'Result'
		Result=IIF(func('Местонахождение',otg_ТекущийИгрок,'Яблоко','Лужайка',НЕТ)=ДА,Использовать,Пропускать)
	}
	!----------
	GS 'Поместить',0,'Яблоко','Лужайка',БезОбработчиков
	!----------
	GS 'ПриНажатииНаСсылку','Яблоко',{
		$ARGS['М']=$ARGS[0]
		!----------
		if func('Местонахождение','Игрок','Яблоко','Игрок',НЕТ)=НЕТ:
			GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Взять яблоко',$ico['взять'],{
				GS 'ДействиеНаЭкран',$ARGS[0]
				if func('Переместить','Игрок','Яблоко',0,'Игрок')=Продолжить:
					GS 'ТекстНаЭкран','п. Вы взяли ((яблоко|Яблоко)).'
				end
			}
		else
			GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Засунуть яблоко в сумку',$ico['положить'],{
				GS 'ДействиеНаЭкран',$ARGS[0]
				if func('Переместить','Игрок','Яблоко','Игрок','Сумка')=Продолжить:
					GS 'ТекстНаЭкран','п. Вы засунули ((яблоко|Яблоко)) в ((сумку|Сумка)).'
				end
			}
			GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Положить яблоко в чугунок',$ico['положить'],{
				GS 'ДействиеНаЭкран',$ARGS[0]
				if func('Переместить','Игрок','Яблоко','Игрок','Чугунок')=Продолжить:
					GS 'ТекстНаЭкран','п. Вы положили ((яблоко|Яблоко)) в ((чугунок|Чугунок)).'
				end
			}
			GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Положить яблоко на траву',$ico['положить'],{
				GS 'ДействиеНаЭкран',$ARGS[0]
				if func('Переместить','Игрок','Яблоко','Игрок','Лужайка')=Продолжить:
					GS 'ТекстНаЭкран','п. Вы положили ((яблоко|Яблоко)) на траву.'
				end
			}
		end
	}
	!----------
	--- Предметы.Яблоко.Заполнить
	!--------------------------------------------------------------------------------
#Предметы.Чугунок.Заполнить
	GS 'УстановитьОписание','Чугунок','чугунок','
		п. Круглый чугунный ((горшок|Чугунок)). Даже немного закопчённый.
	'
	!----------
	GS 'УстановитьОписание','Чугунок:Содержимое','чугунок','
		п. Вместительный такой ((горшок|Чугунок)).
	','','','Содержимое','На дне лежит|На дне лежат:'
	!----------
	GS 'Поместить',0,'Чугунок','Лужайка',БезОбработчиков
	!----------
	GS 'ПриНажатииНаСсылку','Чугунок',{
		$ARGS['М']=$ARGS[0]
		!----------
		GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Осмотреть чугунок',$ico['осмотреть снаружи'],{
			GS 'ДействиеНаЭкран',$ARGS[0]
			GS 'ОписаниеНаЭкран','Чугунок'
		}
		!----------
		GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Заглянуть внутрь чугунка',$ico['осмотреть внутри'],{
			GS 'ДействиеНаЭкран',$ARGS[0]
			GS 'ОписаниеНаЭкран','Чугунок:Содержимое'
		}
	}
	!----------
	--- Объекты.Сундук.Заполнить
	!--------------------------------------------------------------------------------
#Предметы.Сумка.Заполнить
	GS 'УстановитьОписание','Сумка','Походная сумка','
		п. Потёртая кожанная ((сумка|Сумка)).
	'
	!----------
	GS 'УстановитьОписание','Сумка:Содержимое','Походная сумка','
		п. Внутри ((сумки|Сумка)) много разных отделений.
	','','','Содержимое','В сумке есть|В сумке есть:'
	!----------
	GS 'Поместить',0,'Сумка','Лужайка',БезОбработчиков
	!----------
	GS 'ПриНажатииНаСсылку','Сумка',{
		$ARGS['М']=$ARGS[0]
		!----------
		GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Осмотреть сумку',$ico['осмотреть снаружи'],{
			GS 'ДействиеНаЭкран',$ARGS[0]
			GS 'ОписаниеНаЭкран','Сумка'
		}
		!----------
		GS 'Меню.ДобавитьПунктСМодулем',$ARGS['М'],'Покопаться в сумке',$ico['осмотреть внутри'],{
			GS 'ДействиеНаЭкран',$ARGS[0]
			GS 'ОписаниеНаЭкран','Сумка:Содержимое'
		}
	}
	!----------
	--- Объекты.Сундук.Заполнить
	!--------------------------------------------------------------------------------
#Персонажи.Игрок.Заполнить
	GS 'УстановитьТекущегоПерсонажа','Игрок'
	!----------
	GS 'Поместить',0,'Игрок','Лужайка',БезОбработчиков
	!----------
	--- Персонажи.Игрок.Заполнить
	!--------------------------------------------------------------------------------