#Начало
	if QSPVER<'5.7.0':
		if USEHTML:
			*P '<h1>Устаревшая версия QSP</h1>'
			*P '<p align=justify>Версия QSP-плеера, который вы используете, устарела. Для игры требуется версия не ниже 5.7.0. Скачать последнюю версию вы всегда можете с сайта <a class="plain" href="http://qsp.su">qsp.su</a>.</p>'
		else
			*NL 'Устаревшая версия QSP'
			*NL 'Версия QSP-плеера, который вы используете, устарела. Для игры требуется версия не ниже 5.7.0. Скачать последнюю версию вы всегда можете с сайта http://qsp.su.'
		end
		EXIT
	end
	!----------
	KILLALL & CLS & CLOSE ALL
	!----------
	ADDQST 'libs\ObjectQSP.qsp' & GS 'ObjectQSP.Инициализация',0
	!----------
	!Загружаем визуальную тему игры
	GS 'Темы.Загрузить','Default'
	!----------
	GS 'ЗаполнитьДанные'
	!----------
	GS 'НачатьИгру','Стол'
	!----------
	--- Начало
	!-------------------------------------------------------------------------------
#ЗаполнитьДанные
	!Добавляем локации
	GS 'СоздатьЛокацию','Стол'
	!----------
	!Добавляем персонажей
	GS 'СоздатьПерсонажа','Игрок'
	!----------
	!Добавляем предметы
	GS 'СоздатьОбъект','Сигарета'
	GS 'СоздатьОбъект','Портсигар'
	!----------
	!Заполняем игровой сценарий пообъектно
	GS 'Игра.ЗаполнитьОбъекты'
	!----------
	--- ЗаполнитьДанные
	!-------------------------------------------------------------------------------
#Локации.Стол.Заполнить
	GS 'УстановитьОписание','Стол','Стол','
		п. Вы сидите за простым деревянным ((столом|$ОБЪЕКТ)).
	','','','Содержимое'
	!----------
	GS 'УстановитьДействие','Стол','Осмотреться',$ico['осмотреть снаружи'],0,0,{
			GS 'ОписаниеНаЭкран',$ОБЪЕКТ
		}
	!----------
	--- Локации.Стол.Заполнить
	!--------------------------------------------------------------------------------
#Предметы.Сигарета.Заполнить
	GS 'УстановитьОписание','Сигарета','сигарета','
		п. С виду - обычная ((сигарета|$ОБЪЕКТ)) с фильтром.
	'
	!----------
	GS 'УстановитьУпоминание','Сигарета:Упоминание в описании','Стол:Описания','п. На столе лежит ((сигарета|Сигарета)).',{
		ARGS['Результат']=IIF(func('Местонахождение',ИГРОК,'Сигарета','Стол')=ДА,Использовать,Пропускать)
	}
	!----------
	GS 'Поместить','Сигарета','Портсигар'
	GS 'Поместить','Сигарета','Игрок'
	!----------
	GS 'УстановитьДействие','Сигарета','Осмотреть сигарету',$ico['осмотреть снаружи'],0,0,{
			GS 'ОписаниеНаЭкран',$ОБЪЕКТ
		}
	!----------
	GS 'УстановитьДействие','Сигарета','Взять сигарету',$ico['взять'],{
			Result=IIF(func('Местонахождение',$ОБЪЕКТ,ИГРОК),Пропускать,Использовать)
		},'',{
			if func('Переместить',ИГРОК,$ОБЪЕКТ,0,ИГРОК)=Продолжить:
				GS 'ТекстНаЭкран','п. Вы взяли ((сигарету|$ОБЪЕКТ)).'
			end
		}
	!----------
	GS 'ДобавитьВзаимодействие','Сигарета','Стол','Положить сигарету на стол',$ico['положить'],{
			Result=IIF(func('Местонахождение',$ОБЪЕКТ,'Стол'),Пропускать,Использовать)
		},0,{
			if func('Переместить',ИГРОК,$ОБЪЕКТ1,0,$ОБЪЕКТ2)=Продолжить:
				GS 'ТекстНаЭкран','п. Вы положили ((сигарету|$ОБЪЕКТ1)) на ((стол|$ОБЪЕКТ2)).'
			end
		}
	GS 'ДобавитьВзаимодействие','Сигарета','Портсигар','Засунуть сигарету в портсигар',$ico['положить'],{
			Result=IIF(func('Местонахождение',$ОБЪЕКТ,'Портсигар'),Пропускать,Использовать)
		},0,{
			if func('Переместить',ИГРОК,$ОБЪЕКТ1,0,$ОБЪЕКТ2)=Продолжить:
				GS 'ТекстНаЭкран','п. Вы засунули ((сигарету|$ОБЪЕКТ1)) в ((портсигар|$ОБЪЕКТ2)).'
			end
		}
	!----------
	--- Предметы.Сигарета.Заполнить
	!--------------------------------------------------------------------------------
#Предметы.Портсигар.Заполнить
	GS 'УстановитьОписание','Портсигар','портсигар','
		п. Простой металлический ((портсигар|Портсигар)), обтянутый кожей. На крышке выдавлена какая-то надпись.
	','','','Содержимое','В портсигаре лежит|В портсигаре лежат:'
	!----------
	GS 'УстановитьУпоминание','Портсигар:Упоминание в описании','Стол:Описания','
		п. Прямо перед вами лежит ((портсигар|Портсигар)).
	',{
		ARGS['Результат']=IIF(func('Местонахождение',ИГРОК,'Портсигар','Стол')=ДА,Использовать,Пропускать)
	}
	!----------
	GS 'Поместить','Портсигар','Стол'
	!----------
	GS 'УстановитьДействие','Портсигар','Осмотреть портсигар',$ico['осмотреть снаружи'],0,0,{
			GS 'ОписаниеНаЭкран',$ОБЪЕКТ
		}
	!----------
	--- Предметы.Портсигар.Заполнить
	!--------------------------------------------------------------------------------
#Персонажи.Игрок.Заполнить
	GS 'УстановитьТекущегоПерсонажа','Игрок'
	!----------
	GS 'Поместить','Игрок','Стол'
	!----------
	--- Персонажи.Игрок.Заполнить
	!--------------------------------------------------------------------------------