'--------------------------------------------------------------------------------
' FullScreen
' Нужно ли после запуска разворачивать игру на полный экран.
' При этом панель с системным меню плеера ("Квест", "Игра", "Установки", "Помощь")
' тоже пропадает.
'----------
' LibFile
' Цепочка символов, характерная для подключаемых qsp-библиотек.
' Если файл содержит данную цепочку, то он игнорируется
'----------
' Player
' Директория и имя файла с QSP-плеером относительно корневой директории игры
'----------
prmFullScreen	= true
prmLibFile		= "_lib_"
prmPlayer		= "qsp\qspgui.exe"
'--------------------------------------------------------------------------------
' Создаём объект для работы с файлами
set FS=CreateObject("Scripting.FileSystemObject")
' Получаем текущую директорию
set FOLDER=FS.GetFolder(FS.GetAbsolutePathName("."))
' Перебираем файлы в текущей директории
for each FILE in FOLDER.Files
	' Если очередной файл имеет расширение ".qsp" - он нам подходит
	if lcase(mid(FILE.Name,len(FILE.Name)-3))=".qsp" then
		' Если файл не содержит цепочки символов, характерных для qsp-библиотеки,
		' то он подходит нам ешё больше
		if instr(1,lcase(FILE.Name),prmLibFile)=0 then
			set FTR=CreateObject("WScript.Shell")
			' Запускаем QSP-плеер с найденным qsp-файлом
			set GAME=FTR.Exec(prmPlayer&" "&FILE.Name)
			' Если включён режим запуска в полноэкранном режиме, то пытаемся
			' послать окну с игрой комбинацию клавиш Alt+Enter
			if prmFullScreen then
				' Но сперва подождём, пока окно не станет активным
				do
				loop while not FTR.AppActivate(GAME.ProcessID)
				' А вот теперь посылаем комбинацию клавиш Alt+Enter
				FTR.SendKeys "%~"
			end if
			exit for
		end if
	end if
next
'--------------------------------------------------------------------------------