Forum.iFiction.Ru

#диалог
$topic = $ARGS[0]

IF $topic = 'прежний':
    'Да милостью барина живы да сыты. Барин у нас щедрый, не то что прежний.'
ELSEIF $topic = 'добраться':
    'Да вот по этой дороге и беги, только на развилке держись прямо<, а то налево псарни - тебе там будут не рады.>'
ELSEIF $topic = 'меняется':
    'Как часто здесь меняется - не знаем, мы сами не местные. Батрачим то тут, то там по сезонам. А в этих местах впервые.'
END

IF $topic = '':
    ACT 'Эй, косари! До барина-то вашего добраться как?':
        $SELACT
        'Здорово, котище. А ты по этой дорожке беги, только на развилке налево прими - так короче будет.'
        CLA
        ACT 'Последовать совету': GOTO 'псарни'
    END
    ACT 'Косари, а косари, как сами-то? Живы-здоровы?':
        $SELACT
        XGOTO $CURLOC, 'прежний'
    END
END
IF $topic = 'псарни':
    ACT 'Плохие вы путникам советы даете...':
        $SELACT
        'Ну если путники к нам без уважения, то и нам резона нет. А дорога до замка там и вправду короче.'
        XGOTO $CURLOC, 'груб'
    END
END
IF $topic = 'груб':
    ACT 'Эх, косари! Поколотил бы я вас, да времени нет!':
        GOTO 'конец'
    END
    ACT 'Ну простите, если груб был. Как сами-то? Как живется, как работается?':
        $SELACT
        XGOTO $CURLOC, 'прежний'
    END
END
IF $topic = 'прежний' OR $topic = 'меняется':
    ACT 'А как добраться до барина вашего?':
        $SELACT
        XGOTO $CURLOC, 'добраться'
    END
END
IF $topic = 'прежний':
    ACT '<Прежний?> И часто у вас здесь барин меняется?':
        $SELACT
        XGOTO $CURLOC, 'меняется'
    END
END
IF $topic = 'добраться':
    ACT 'А из местных тут живет кто-нибудь?':
        $SELACT
        'Ну... у леса можно встретить полоумную старуху - вот она вроде из местных.'
        CLA
        ACT 'Ок': GOTO 'конец'
    END
END
ACT 'Побегу-ка я дальше...':
    GOTO 'конец'
END
----
#псарни
'Псарни.'
ACT 'Еле унести ноги': GOTO 'диалог', 'псарни'
----
#конец
'конец'
----