Forum.iFiction.Ru

iFiction.Ru · ifHub · FAQ · IFWiki · QSP · URQ · INSTEAD · AXMA

форум об interactive fiction, текстовых приключенческих играх и всём таком...

Вы не зашли.

0    0    #1
26.02.2008 16:35

gaev_dg
Участник
Зарегистрирован: 22.02.2008
Сообщений: 9

Русский Информ (опять)

Здравствуйте все! Меня очень долго, года с 2005-го, на форуме не было -- но, вообще-то, бывший dennis -- это я и есть. wink И локализацией "Информа" занимался я. Очень рад, что платформа вроде не заброшена, и даже появляются русские переводы таких замечательных игр, как All Roads.

Так что любые вопросы по поводу RInform'у можно задавать мне. Я постараюсь ответить.
(И отдельное спасибо GrAnd-у, за информацию об этом форуме и приглашение сюда. wink )

Отредактировано gaev_dg (26.02.2008 16:38)

Неактивен

0    0    #2
26.02.2008 17:06

fireton
некто с бородой (+354, -92)
Откуда: Москва
Зарегистрирован: 22.08.2005
Сообщений: 1103
Вебсайт

Тон

Re: Русский Информ (опять)

Замечательно! Welcome back, Денис!

Неактивен

0    0    #3
12.05.2008 20:03

GAGarinson
Участник
Откуда: Саров, Нижегородская обл.
Зарегистрирован: 08.05.2008
Сообщений: 4

Re: Русский Информ (опять)

Спасибо за работу, Денис.

Надеюсь, что обещанный на ifwiki.ru Rinform версии 0.8 не заставит себя слишком долго ждать. А пока одно пожелание и один баг-репорт.

Пожелание. Думаю, что стоит вынести как отдельные игры на тот же ifwikw.ru переведенные тестово-учебные образцы из библиотечного пакета. Во-первых, это резко расширит список русифицированных игр на Inform. smile А во-вторых, потенциальным авторам будет полезно и приятно знать, что есть на чем проводить начальное освоение языка разработки в его русской ипостаси. Да и тот же Адвент - вполне себе самостоятельные произведение и вообще "Гринвичский меридиан" для IF, а других его воплощений на русский мне не попадалось.

Баг-репорт. Небольшой кусок прохождения Алисы из всё того же библиотечного пакета.

>сесть в кресло
Алиса забралась с ногами в мягкое удобное кресло.

Всё прекрасно, предлог корректно обработан парсером. Скорей всего, он просто пропущен (так глубоко я еще не копал, чтобы утверждать с уверенностью). Но сам факт корректной обработки предлога "в" заставил меня посчитать кресло контейнером. Поэтому через пару ходов я отдал команду не совсем по-русски. Я знаю, что мы садимся В кресло, а кладем что-то НА него, но считая в уме кресло контейнером, а не поверхностью (опорой), я получил следующий кусок текста.

>положить котенка в кресло
(белый котенок в кресло)
Кресло не  что-либо содержать.

Черный котенок катается по полу.

>положить котенка на кресло
(белый котенок на кресло)
Белый котенок, спрыгнув с кресла, ловко приземлился на полу и убежал прочь.

Цветом выделен мелкий, но явный баг перевода. Некорректно составлено сообщение о невозможности поместить что-то внутрь объекта, не являющегося контейнером. Опять же, глубоко еще не копал, но предполагаю, что это сообщение формируется в библиотечных файлах, так что есть шанс поправить его к версии 0.80.

Неактивен

0    0    #4
12.05.2008 21:35

yandexx
Z-машина (+46, -3)
Откуда: Санкт-Петербург
Зарегистрирован: 01.06.2007
Сообщений: 394
Вебсайт

Русский Информ
Информ Discord

Re: Русский Информ (опять)

Отрадно видеть людей (добро пожаловать на форум, GAGarinson!), интересующихся Информом. Хочется, чтобы наши авторы делали больше игр на парсерных платформах. Очень уж примитивной кажется мне CYOA-система.

В своих переводах я модифицировал переведённую библиотеку, заменив «вы» на «ты» в сообщениях самому персонажу и оставляя «вы» в сообщениях, адресованных игроку. Также исправил пару багов, я думаю. Если это действительно нужно, могу выложить.

Ещё есть идея создания перевода Inform's Beginner Manual (http://www.firthworks.com/roger/IBG.html) для привлечения новых адептов Информа. smile

Неактивен

0    0    #5
12.05.2008 22:24

GAGarinson
Участник
Откуда: Саров, Нижегородская обл.
Зарегистрирован: 08.05.2008
Сообщений: 4

Re: Русский Информ (опять)

yandexx написал:

В своих переводах я модифицировал переведённую библиотеку, заменив «вы» на «ты» в сообщениях самому персонажу и оставляя «вы» в сообщениях, адресованных игроку. Также исправил пару багов, я думаю. Если это действительно нужно, могу выложить.

Ещё есть идея создания перевода Inform's Beginner Manual (http://www.firthworks.com/roger/IBG.html) для привлечения новых адептов Информа. smile

Модифицированная библиотека будет полезна, даже как учебное пособие: "Найдите 10 отличий и поймите, почему второе лучше первого".

А вот IBG я бы переводить не стал. Программист-разработчик, imho, всё равно должен знать английский, "по-любому". Да и азбука в стишках-эпиграфах напрямую непереводима, и буквицы в начале глав клёвые. Опять же, почти 300 страниц в основном технического текста при условии не устоявшейся русской терминологии - очумеешь. А вот игры-примеры можно и перевести, снабдив подробными комментариями. Правда, сам я дальше Heidi пока не продвинулся.

Впрочем, если бы подобралась хорошая компания в 2-4 человека, то можно и IBG, и DM4 попробовать перевести. Просто любой текст после написания (перевода) надо вычитывать. А практический опыт авторской и редакторской работы говорит мне, что своих ляпов не видишь в упор.

Неактивен

0    0    #6
12.05.2008 22:38

yandexx
Z-машина (+46, -3)
Откуда: Санкт-Петербург
Зарегистрирован: 01.06.2007
Сообщений: 394
Вебсайт

Русский Информ
Информ Discord

Re: Русский Информ (опять)

GAGarinson написал:

Программист-разработчик, imho, всё равно должен знать английский, "по-любому". Да и азбука в стишках-эпиграфах напрямую непереводима, и буквицы в начале глав клёвые. Опять же, почти 300 страниц в основном технического текста при условии не устоявшейся русской терминологии - очумеешь. А вот игры-примеры можно и перевести, снабдив подробными комментариями. Правда, сам я дальше Heidi пока не продвинулся.

Это верно. А за эти примеры, пожалуй, действительно стоит взяться!

GAGarinson написал:

А практический опыт авторской и редакторской работы говорит мне, что своих ляпов не видишь в упор.

Это факт.

EDIT: Кстати, я три дня назад выложил переведённую Денисом Adventure: http://ifwiki.ru/Приключение

Отредактировано yandexx (12.05.2008 22:39)

Неактивен

0    0    #7
14.05.2008 19:35

GAGarinson
Участник
Откуда: Саров, Нижегородская обл.
Зарегистрирован: 08.05.2008
Сообщений: 4

Re: Русский Информ (опять)

Раз специального раздела про Inform нету, то продолжу здесь, чтоб не растекаться темами по форуму.

Осваивая IBG заодно пытаюсь и переводить. Первый опыт - перевод игры-примера Хейди. Замечания, что я не так русифицировал, приветствуются.

Код:

!=============================================================================
Include "CyrDef";
Constant Story "Хейди";
Constant Headline
    "^Пример простой игры на Inform.
     ^Авторы: Роджер Фирт (Roger Firth) и Соня Кессерих (Sonja Kesserich).
     ^Перевод Юрия Салтыкова a.k.a. G.A. Garinson^";
     
Constant MAX_CARRIED 1;

Include "Parser";
Include "VerbLib";
!============================================================================
! Описание игровых объектов

Object before_cottage "Перед домом"
    with description
            "Ты стоишь около избушки, на восток от которой раскинулся лес.",
        e_to forest,
        in_to "Такой славный денек... Он слишком хорош, чтобы прятаться внутри.",
        cant_go "Единственный путь ведет на восток.",
    has light;
    
Object cottage "маленький домик" before_cottage
    with description "Домик мал и неказист, но ты очень счастлива, живя здесь.",
        name 'маленьк' 'дом' 'изб' 'терем' 'коттедж' 'хат' 'небольш' 'строен'
            'домик' 'избушк' 'теремок' 'хатк',
        before [;
            Enter:
                print_ret "Такой славный денек... 
                    Он слишком хорош, чтобы прятаться внутри.";
            ],
        has scenery;

Object forest "В лесной чаще"
    with description
            "На западе, сквозь густую листву, можно разглядеть небольшое строение.
            Тропинка ведет на северо-восток",
        w_to before_cottage,
        ne_to clearing,
    has light;

Object bird "птенчик" forest
    with description "Слишком мал, чтобы летать, птенец беспомощно попискивает.",
        name 'детеныш' 'птиц' 'птичк' 'птенчик' 'птенц' 'маленьк',
        before [;
            Listen:
                print "Жалобный писк испуганной птички разрывает тебе сердце. 
                    Надо помочь!^";
                return true;
        ],
    has ;

Object clearing "Полянка"
    with description
            "Посреди полянки стоит высокий платан.
             Тропинка вьется меж деревьев, уводя на юго-запад.",
        sw_to forest,
        u_to top_of_tree,
    has light;

Object nest "птичье гнездо" clearing
    with description "Гнездо сплетено из прутиков и аккуратно устлано мхом.",
        name 'птичь' 'гнезд' 'гнездышк' 'пруть' 'прутик' 'мох',
    has container open;

Object tree "Высокий платан" clearing
    with description
        "Величавое дерево стоит посреди поляны.
         Кажется, по его стволу будет несложно влезть наверх.",
        name 'высок' 'платан' 'дерев' 'ствол' 'величав',
        before [;
            Climb:
                PlayerTo(top_of_tree);
                return true;
        ],
    has scenery;

Object top_of_tree "На верхушке дерева"
    with description "На этой высоте цепляться за ствол уже не так удобно.",
        d_to clearing,
        after [;
            Drop:
                move noun to clearing;
                return false;
        ],
    has light;

Object branch "надежный толстый сук" top_of_tree
    with description "Сук достаточно ровный и крепкий, чтобы на нем надежно 
                      держалось что-то не очень большое.",
        name 'надежн' 'ровн' 'толст' 'крепк' 'сук' 'ветк',
        each_turn [; if (bird in nest && nest in branch) deadflag = 2; ],
    has static supporter;

!============================================================================
! Entry point routines
[ Initialise; location = before_cottage;];

!============================================================================
! Stanard and extended grammar
Include "RussiaG";

!============================================================================

А вот ссылка на исходник и откомпилированную игру в маленьком архиве http://ifolder.ru/6559217.

Кстати, намедни наткнулся на инфу, что Glulx, начиная с версии 3.0 понимает Unicode. Никто с русским не пробовал играться?

Неактивен

0    0    #8
15.05.2008 20:22

yandexx
Z-машина (+46, -3)
Откуда: Санкт-Петербург
Зарегистрирован: 01.06.2007
Сообщений: 394
Вебсайт

Русский Информ
Информ Discord

Re: Русский Информ (опять)

Хороший перевод, спасибо!

Чего не хватало: атрибутов рода (male, female, neuter), которые нужны, чтобы игра и сам игрок могли обращаться к предметам словами "его", "её" и т.п.; также указания изменяемых частей слов, напр. "маленьк/ий домик/", чтобы игра могла правильно склонять названия предметов. Эти детали идут чисто из RInform.

Я исправил исходник и выложил вместе со скомпилированной игрой и батником для компиляции, который будет работать при условии, что компилятор лежит в той же папке, что .bat, а библиотека в папке lib.

Про Glulx: да, действительно, в версии 3.0 поддерживается Unicode, и на сайте у Эндрю Плоткина есть соответствующие патчи к компилятору, которые вроде бы уже включены в ту версию, что идёт с Infrom 7 (Inform 6.31 N), но и в ней он выдаёт ошибку, что "Glulx ещё не поддерживает Unicode". Я бы сам пересобрал компилятор с этими пачтами, но сейчас никакого желания возиться с GCC/MinGW нет. Хотя под линуксом можно и попробовать...

Ещё скоро постараюсь выложить мой мод библиотеки RInform.

Неактивен

0    0    #9
15.05.2008 20:55

GAGarinson
Участник
Откуда: Саров, Нижегородская обл.
Зарегистрирован: 08.05.2008
Сообщений: 4

Re: Русский Информ (опять)

Спасибо за помощь. Сравнивая 2 варианта легче понять принципы русификации на Inform.

А от необходимости в батниках я избавился. Удалось приручить WIDE, что он у меня и компилирует со всеми ключами, необходимыми для русской версии, и запускает по кнопке прямо из редактора . Редактор не самый удобный, в частности напрягает невозможность выставить размер табуляции, но за удобную компиляцию и вывод сообщений компилятора прямо в окно среды разработки я многое готов простить. Хорошо было бы, если б автор не остановился на текущей бете.

Неактивен

0    0    #10
01.08.2009 20:28

yandexx
Z-машина (+46, -3)
Откуда: Санкт-Петербург
Зарегистрирован: 01.06.2007
Сообщений: 394
Вебсайт

Русский Информ
Информ Discord

Re: Русский Информ (опять)

Если это кому-нибудь интересно, то я только что выложил свою версию библиотеки RInform.

http://ynd.stormway.ru/files/if/RInform075-mod.zip

Список изменений не сильно велик:
* во всех текстах вместо обращения на "вы" используется обращение на "ты", за исключением ситуаций, когда игра обращается к игроку, а не к персонажу (например, при сохранении -- на "вы"),
* кавычки заменены с простых на более корректные в русском языке « и » (символы ’@<<’ и ’@>>’),
* исправлено несколько мелких багов, а также некоторые строки в переводе библиотеки,
* возвращены глаголы для действия Strong.

Неактивен

0    0    #11
22.03.2010 15:57

yandexx
Z-машина (+46, -3)
Откуда: Санкт-Петербург
Зарегистрирован: 01.06.2007
Сообщений: 394
Вебсайт

Русский Информ
Информ Discord

Re: Русский Информ (опять)

В связи с возросшим на канале интересом к платформе, открыл сайт:

http://rinform.stormway.ru/

Неактивен

0    0    #12
10.03.2011 17:47

yandexx
Z-машина (+46, -3)
Откуда: Санкт-Петербург
Зарегистрирован: 01.06.2007
Сообщений: 394
Вебсайт

Русский Информ
Информ Discord

Re: Русский Информ (опять)

С некоторыми изменениями обновлена сборка RInform на сайте:
http://rinform.stormway.ru/

А также открыт репозиторий на GitHub:
https://github.com/yandexx/RInform
git://github.com/yandexx/RInform.git

Неактивен

Powered by PunBB
© copyright 2001–2024 iFiction.Ru