:menu
proc cls
textcolor = 0xffaaaa
textfont = "content/font2.ttf[30]"
textalign=3
pln #%gametitle$
proc image('content/tuskub_desert.jpg')
textalign=2
textfont = "content/font.ttf[20]"
linkcolor = 0xc1d2de
textfont = "content/font1.ttf[20]"
pln Посвящается Владимиру...
textalign=1
textfont = "content/font.ttf[20]"
textcolor = 0xc1d2de
proc btn('about','Об игре и авторе')
proc btn('thanks','Благодарности')
proc btn('begin','Игра')
if gss_save_flg then proc btn('contin','Продолжить игру')
proc btn_on
end

:common
:cls
cls
textpane_top = 355      ; выделяем текстовое окно
textpane_height = 700-355-16
decoradd разделитель1 (105, 33, 0) RECT 565, 1, 0xFF202F16   ; это я ставлю свою полоску разделитель вместо фурковской
decoradd разделитель2 (105, 34, 0) RECT 565, 1, 0xFF2E3F24
decoradd разделитель3 (105, 35, 0) RECT 565, 1, 0xFF485740
decoradd разделитель4 (105, 36, 0) RECT 565, 1, 0xFF2E3F24
decoradd разделитель5 (105, 37, 0) RECT 565, 1, 0xFF202F16

decoradd разделитель6 (20, 700-4, 0) RECT 760, 2, 0xFF485740 ; это разделитель перед кнопками
btn_id = 0                  ; обнуление счетчика кнопок
decordel кнопка*        ; очистка кнопок-декораторов
end

:btn
if btn_id > 4 then goto top_up                                                    ; если кнопок больше 5-ти, то обрабатываем в top_up
decoradd кнопка_#btn_id$ (20, 700+btn_id*36, 0) TEXTBUTTON btn_2, btn_1  ;выводим кнопку
decor_кнопка_#btn_id$_enabled = 0               ;деактивируем её
btn_id = btn_id + 1             ;увеличиваем счётчик для следующей кнопки
end

:btn_on
pause 140       ;пауза перед активацией кнопок
opt_id = 0
:btn_enable
decor_кнопка_#opt_id$_enabled = 1           ;активируем все кнопки
if opt_id <> btn_id then opt_id = opt_id + 1 & goto btn_enable
end


:top_up
topup = btn_id-4
textpane_height = 700-355-16-36*topup           ;уменьшаем высоту текстового окна на одну строку
decoradd разделитель6 (20, 700-4-36*topup, 0) RECT 760, 2, 0xFF485740     ;переносим разделитель на строку выше

bopt=0
:next_top_up
decor_кнопка_#bopt$_y = decor_кнопка_#bopt$_y - 36           ;переносим кнопки на строку выше (строка=36 пикс.)
if bopt <> btn_id then bopt = bopt + 1 & goto next_top_up  

decoradd кнопка_#btn_id$ (20, 700+4*36, 0) TEXTBUTTON btn_2, btn_1   ;последнюю кнопку ставим на самый низ
btn_id = btn_id + 1        ;увеличиваем счётчик кнопок
end


:image
decoradd картинка (0,40,0) IMAGE image_1           ;вывод декоратора картинки
decor_картинка_x = 800/2 - decor_картинка_width /2          ;центрируем картинку
end